blob: 4de6335348fb1ea2a7757d9a8bc25117ee425d6c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Mantas Mikulėnas <grawity@gmail.com>
pkgname=realmd
pkgver=0.16.3
pkgrel=2
pkgdesc="DBus service for joining hosts to Active Directory and FreeIPA realms"
arch=(i686 x86_64)
url="https://freedesktop.org/software/realmd/"
license=(GPL3)
depends=(adcli dbus krb5 openldap packagekit polkit)
optdepends=('sssd: Active Directory, FreeIPA, LDAP client'
'samba: traditional Active Directory client')
makedepends=(docbook-xsl intltool python xmlto)
checkdepends=(python2)
source=("https://www.freedesktop.org/software/realmd/releases/$pkgname-$pkgver.tar.gz"
"https://www.freedesktop.org/software/realmd/releases/$pkgname-$pkgver.tar.gz.sig")
sha256sums=('d8943f66a2a666fee8be026d82a66904c0a5125aab7ef74504456ce269687dda'
'SKIP')
validpgpkeys=('C0F67099B808FB063E2C81117BFB1108D92765AF')
prepare() {
cd "$pkgname-$pkgver"
sed -i '1s/\<python\>/&2/' build/tap-*
}
build() {
cd "$pkgname-$pkgver"
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--localstatedir=/var \
--with-distro=defaults ;
make
}
check() {
cd "$pkgname-$pkgver"
make check
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" DBUS_POLICY_DIR="/usr/share/dbus-1/system.d" install
}
# vim: ts=2:sw=2:et
|