blob: ea3ae7cdbc21ca809d360cbb4a6e77ca9e5ce88c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Mantas Mikulėnas <grawity@gmail.com>
pkgname=realmd-git
_pkgname=realmd
pkgver=0.16.3.r9.g2cab2d4
pkgrel=1
pkgdesc="DBus service for joining hosts to Active Directory and FreeIPA realms"
arch=(i686 x86_64)
url="https://freedesktop.org/software/realmd/"
license=(GPL3)
depends=(adcli dbus krb5 openldap packagekit polkit)
makedepends=(docbook-xsl intltool xmlto)
checkdepends=(python2)
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("git+https://anongit.freedesktop.org/git/realmd/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe | sed 's/-/.r/; s/-/./g'
}
prepare() {
cd "$_pkgname"
sed -i '1s/\<python\>/&2/' build/tap-*
}
build() {
cd "$_pkgname"
NOCONFIGURE=1 ./autogen.sh
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--localstatedir=/var \
--with-distro=defaults ;
make
}
check() {
cd "$_pkgname"
make check
}
package() {
cd "$_pkgname"
make DESTDIR="$pkgdir" install
}
# vim: ts=2:sw=2:et
|