blob: 19f10ac351ecb192253c60d6aeaf62fcf8f3e09f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Nocifer <apmichalopoulos at gmail dot com>
# Contributor: david0
pkgname=reaper-bin
pkgver=6.44
pkgrel=1
pkgdesc="A complete digital audio production application for computers, offering a full multitrack audio and MIDI recording, editing, processing, mixing and mastering toolset"
arch=('x86_64' 'i686' 'aarch64' 'armv7l')
url="https://reaper.fm"
license=('custom')
depends=('gtk3' 'desktop-file-utils' 'xdg-utils' 'aribb24')
optdepends=('jack' 'pulseaudio')
provides=("reaper=${pkgver}" 'lv2-host' 'vst-host' 'vst3-host')
source_x86_64=("https://reaper.fm/files/6.x/reaper${pkgver//.}_linux_x86_64.tar.xz")
source_i686=("https://reaper.fm/files/6.x/reaper${pkgver//.}_linux_i686.tar.xz")
source_aarch64=("https://reaper.fm/files/6.x/reaper${pkgver//.}_linux_aarch64.tar.xz")
source_armv7l=("https://reaper.fm/files/6.x/reaper${pkgver//.}_linux_armv7l.tar.xz")
sha256sums_x86_64=('729e3b5f8d9fd3d54316881641a06fa5dc381bb495adb2b1e0ff999d56cd53c7')
sha256sums_i686=('ea28242b69496259eec3a1272cedd96342bdf61a729888ab2039d1f8924820f6')
sha256sums_aarch64=('102f1314173a6504b72a906e3f0f151a59cc0a0cf28f5a22f26cda450696e864')
sha256sums_armv7l=('356c14fed1304e26293d888acceafa0c3ff3551a8e587934eaf25b4f003bfd45')
_arch=$(uname -m)
package() {
XDG_DATA_HOME="${srcdir}/desktop" sh "${srcdir}/reaper_linux_${_arch}/install-reaper.sh" --install "${pkgdir}/opt" --integrate-user-desktop
rm "${pkgdir}/opt/REAPER/uninstall-reaper.sh"
mkdir -p "${pkgdir}/usr/bin"
ln -s /opt/REAPER/reaper "${pkgdir}/usr/bin/reaper"
mkdir -p "${pkgdir}/usr/share/licenses/reaper"
ln -s /opt/REAPER/EULA.txt "${pkgdir}/usr/share/licenses/reaper/LICENSE"
sed -i 's#^Exec.*#Exec="/opt/REAPER/reaper" %F#g' "${srcdir}/desktop/applications/cockos-reaper.desktop"
install -Dm644 "${srcdir}/desktop/applications/cockos-reaper.desktop" "${pkgdir}/usr/share/applications/cockos-reaper.desktop"
install -d "${pkgdir}/usr/share/icons/hicolor/256x256/apps"
install -m644 "${srcdir}/desktop/icons/hicolor/256x256/apps/"*.png "${pkgdir}/usr/share/icons/hicolor/256x256/apps"
install -Dm644 "${srcdir}/desktop/mime/packages/application-x-reaper.xml" "${pkgdir}/usr/share/mime/packages/application-x-reaper.xml"
}
|