blob: 5cf18a41d1875e4ec176d71db3dcea2e9c2d3442 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: duanluan <duanluan@outlook.com>
pkgname=rebased-bin
_pkgname=rebased
pkgver=1.1.8
pkgrel=1
pkgdesc='Standalone JetBrains-based Git client (prebuilt binary)'
arch=('x86_64' 'aarch64')
url='https://github.com/DetachHead/rebased'
license=('Apache-2.0')
depends=('fontconfig' 'giflib' 'hicolor-icon-theme' 'libdbusmenu-glib' 'ttf-font')
optdepends=('xdg-utils: open URLs from IDE')
provides=('rebased')
conflicts=('rebased')
options=('!strip')
source=("${_pkgname}.sh" "${_pkgname}.desktop")
source_x86_64=("${_pkgname}-${pkgver}-x86_64.tar.gz::https://github.com/DetachHead/rebased/releases/download/${pkgver}/rebased.tar.gz")
source_aarch64=("${_pkgname}-${pkgver}-aarch64.tar.gz::https://github.com/DetachHead/rebased/releases/download/${pkgver}/rebased-aarch64.tar.gz")
sha256sums=('e152fc59d093764f826b990c04a64db48d43f1ee8708b265155c16888a9e54bf'
'c9ca95ac0578c7ad1db358afce473475d9d82010676018e157bbdfaaeb256cae')
sha256sums_x86_64=('75d8faaf77f62d1d723675cb517d425a46566f818f1c5f1b311e5b60988ab803')
sha256sums_aarch64=('6f6914fcbd8ece8524dc2ffb34f7d2b9951b9d2018ccfb2b8f6f40f310ccee5f')
package() {
local app_dir
local install_root="${pkgdir}/opt/${_pkgname}"
app_dir="$(find "${srcdir}" -maxdepth 1 -type d -name 'idea-IC-*' | sort | head -n1)"
if [[ -z "${app_dir}" ]]; then
printf 'failed to find extracted Rebased application directory\n' >&2
return 1
fi
install -dm755 "${install_root}"
cp -a "${app_dir}/." "${install_root}/"
install -Dm755 "${srcdir}/${_pkgname}.sh" "${pkgdir}/usr/bin/${_pkgname}"
install -Dm644 "${app_dir}/bin/rebased.svg" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/rebased.svg"
install -Dm644 "${app_dir}/bin/rebased.png" "${pkgdir}/usr/share/pixmaps/rebased.png"
install -Dm644 "${app_dir}/LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
install -Dm644 "${srcdir}/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
}
|