blob: 66b34b48d5c6e6f209887ee6ff04a4e0eb9e18ba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Jean Lucas <jean@4ray.co>
pkgname=redshift-wlr-gamma-control
pkgver=1.12+r25+geecbfed
_commit=eecbfedac48f827e96ad5e151de8f41f6cd3af66
pkgrel=1
pkgdesc='Redshift fork supporting color temperature adjustment with wlroots'
arch=(i686 x86_64)
url=https://github.com/minus7/redshift/tree/wayland
license=(GPL3)
depends=(glib2 hicolor-icon-theme libdrm libxxf86vm python wayland)
makedepends=(git intltool)
optdepends=('python-gobject: for redshift-gtk'
'gtk3: for redshift-gtk'
'geoclue: for geolocation support'
'sway: Wayland environment using the wlr-gamma-control protocol')
provides=(redshift)
conflicts=(redshift)
source=(git+${url/\/tree*/}#commit=$_commit)
sha512sums=('SKIP')
pkgver() {
cd redshift
git describe --long --tags | sed 's#v##;s#-#+#g;s#+#+r#'
}
build() {
cd redshift
./bootstrap
./configure \
--prefix=/usr \
--enable-drm \
--enable-randr \
--enable-vidmode \
--enable-geoclue2 \
--enable-wayland \
--with-systemduserunitdir=/usr/lib/systemd/user
make
}
package() {
cd redshift
make DESTDIR="$pkgdir" install
install -Dm 644 COPYING -t "$pkgdir"/usr/share/licenses/redshift
}
|