blob: 55e3cc84f45d86fc781d59379cff40e0156b05c0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: James Liu <contact at no-bull dot sh>
pkgname=reflector-rs
pkgver=1.1.2
pkgrel=1
pkgdesc='Retrieve and filter the latest Arch Linux mirror list (Rust implementation)'
arch=('x86_64')
url='https://github.com/james7132/reflector-rs'
license=('GPL-2.0-or-later')
provides=('reflector')
conflicts=('reflector')
depends=('openssl')
makedepends=('cargo' 'git' 'rust' 'gzip')
backup=('etc/xdg/reflector/reflector.conf')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('f5673b7a20c2ceb93bb553b5e072688124f1e7e089ced89dae3f5b67c7998632')
prepare() {
cd "$pkgname-$pkgver"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --target "$CARCH-unknown-linux-gnu"
gzip man/reflector.1
}
package() {
cd "$pkgname-$pkgver"
# Install binary
install -Dm755 "target/$CARCH-unknown-linux-gnu/release/reflector" \
"$pkgdir/usr/bin/reflector"
# Install systemd service and timer
install -Dm644 "dist/reflector.service" \
"$pkgdir/usr/lib/systemd/system/reflector.service"
install -Dm644 "dist/reflector.timer" \
"$pkgdir/usr/lib/systemd/system/reflector.timer"
# Install default configuration
install -Dm644 "dist/reflector.conf" \
"$pkgdir/etc/xdg/reflector/reflector.conf"
# Install man page
install -Dm644 "man/reflector.1.gz" "$pkgdir/usr/share/man/man1/reflector.1.gz"
# Install license
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|