blob: d39037efc009c499870dcb69520e12a1e20bf4e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
pkgname=regexxer
pkgver=0.10
pkgrel=13
pkgdesc='Interactive search and replace tool for GNOME'
arch=(x86_64)
url='https://regexxer.sourceforge.net/'
license=(GPL-2.0-or-later)
depends=(
atkmm
dconf
gcc-libs
glib2
glibc
glibmm
gtk3
gtkmm3
gtksourceview4
gtksourceviewmm
hicolor-icon-theme
libsigc++
pangomm
)
makedepends=(
git
intltool
)
source=(
"git+https://gitlab.gnome.org/Archive/$pkgname.git#tag=$pkgname-$pkgver"
regexxer-gtksourceviewmm4.patch
regexxer.appdata.xml
)
b2sums=(
9192c07e2152d87a2b36fa077981d62dc48138775578fb2c23593a9aa8529b5552138e503be82252904551747dbf4425b50ebcc3b285574977a73c6fe2365318
8465c61df06c830264eea9b1624bc957ff00c61f818d6b5d36cc70b659415cd66d5651c2249f9be3caf5204e66d372beb57a2a719101df09bedfd970fc02000d
1b8878c5fbfaccefd3f1157e9905b8e7cc022c9e5def6aa22b7f9dc06b8cad8b632962bf1aac1da763bedee702e14d373119ac66e2f9c07bde22beb9097086a3
)
prepare() {
cd $pkgname
# Port to glib 2.32
git cherry-pick -n 891327ee82e327314429609aeb5a60faed5487ba
# Fix deprecations to make it compatible with GTK 3
git cherry-pick -n 107c71d622c7cfbced8dc23901841dca0f97d505
# Don't try to compile GSettings schemas when packaging
sed -i '/GLIB_COMPILE_SCHEMAS/ d' Makefile.am
# Port to gtksourceviewmm4
git apply -3 ../regexxer-gtksourceviewmm4.patch
autoreconf -fi -I /usr/share/gettext/m4/
}
build() {
cd $pkgname
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
install -Dm644 ../regexxer.appdata.xml "$pkgdir/usr/share/metainfo/regexxer.appdata.xml"
}
|