blob: 5c650ac4c2994866c5794691aa03ffe848e77c54 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: James Knight <james.d.knight@live.com>
pkgname=releng-tool
pkgver=0.17.0
_pkgtarget=v0.17
pkgrel=1
pkgdesc='A tool to manage the building of packages'
url=https://releng.io/
arch=(any)
license=(BSD)
makedepends=(
python
python-build
python-installer
python-wheel
)
optdepends=(
'autoconf: support for autotools package management'
'bash-completion: shell completion for bash'
'bzr: supporting for Bazaar cloning'
'cmake: support for CMake package management'
'cvs: supporting for CVS checkouts'
'fish: shell completion for fish'
'git: support for Git cloning'
'gnupg: support for GPG verification of downloaded packages'
'make: support for building make-dependent packages'
'meson: support for building meson-dependent packages'
'mercurial: support for Mercurial cloning'
'openssh: support for secure-copy fetching of sources'
'patch: support for patching package sources'
'python-certifi: support using Mozilla'\''s CA Bundle for Bazaar cloning'
'python-matplotlib: support for PDF generation of build statistics'
'python-numpy: support for PDF generation of build statistics'
'scons: support for building SCons-dependent packages'
'subversion: supporting for Subversion checkouts'
'zsh-completions: shell completion for zsh'
)
_base_url=https://github.com/releng-tool/releng-tool/releases/download
source=(
$_base_url/$_pkgtarget/releng-tool-$pkgver.tar.gz
$_base_url/$_pkgtarget/releng-tool-$pkgver.tar.gz.asc
)
sha512sums=(
39f7ba06996d3a80a16332ddd4f7bc028e851efa21955ecb0629218a23b39720cc6d37ff3d91afb4a248fbb0826b91dcec76f18721f67c4a832efd369d703547
a0c0baefb803c9c70ad1407a393173cf26e06e635305f77987c560b55ab2c566972d1cbdf482f266e0a91d08fccdd5b17c4255a76127b60cf44f4b660ed96a57
)
validpgpkeys=(D04A27BA9305DBBD354E653902D3C27B922CCC13)
build() {
cd $pkgname-$pkgver
python -m build --wheel --no-isolation
}
package() {
cd $pkgname-$pkgver
python -m installer --destdir="$pkgdir" dist/*.whl
install -vDm644 scripts/completion/bash \
"$pkgdir/usr/share/bash-completion/completions/$pkgname"
install -vDm644 scripts/completion/fish \
"$pkgdir/usr/share/fish/completions/$pkgname.fish"
install -vDm644 scripts/completion/zsh \
"$pkgdir/usr/share/zsh/site-functions/_$pkgname"
install -vDm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|