blob: 742cdf8474ea29f7df66f4003b406d43e7844e30 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Andrew Sun <adsun701 at gmail dot com>
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Andy Weidenbaum <archbaum at gmail dot com>
pkgname=remarshal
pkgver=0.17.1
pkgrel=4
pkgdesc='Convert between CBOR, JSON, MessagePack, TOML, and YAML'
arch=(any)
url="https://github.com/dbohdan/$pkgname"
license=(MIT)
_pydeps=(cbor2
dateutil
tomlkit
u-msgpack
yaml)
depends=(python
"${_pydeps[@]/#/python-}")
makedepends=(python-build python-installer python-wheel python-poetry-core)
conflicts=(haskell-yaml)
options=('!emptydirs')
_archive="$pkgname-$pkgver"
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$_archive.tar.gz")
sha256sums=('826a41d3e3ed9d45422811488d7b28cc146a8d5b2583b18db36302f87091a86d')
prepare() {
cd "$_archive"
rm -rf dist/
}
build() {
cd "$_archive"
python -m build --wheel --no-isolation
}
package() {
cd "$_archive"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
# # remove files owned by haskell-yaml to prevent conflicts
# rm "$pkgdir/usr/bin/json2yaml" "$pkgdir/usr/bin/yaml2json"
}
|