blob: 00d11c8419aac6b78cec990004ba884a90d60890 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
pkgname=renderdoc
pkgver=1.27
pkgrel=4
pkgdesc="OpenGL and Vulkan debugging tool"
arch=(x86_64)
url="https://github.com/baldurk/renderdoc"
license=("MIT")
makedepends=("cmake" "python")
depends=("libx11" "libxcb" "mesa" "libgl" "qt5-base" "qt5-svg" "qt5-x11extras" "xcb-util-keysyms" "pcre" "python")
source=("https://github.com/baldurk/renderdoc/archive/v${pkgver}.tar.gz"
"https://github.com/baldurk/renderdoc/releases/download/v${pkgver}/v${pkgver}.tar.gz.asc")
validpgpkeys=('1B039DB9A4718A2D699DE031AC612C3120C34695')
sha384sums=('41bb70dcb4022f7c5f90191ae6ffc1c456abb00abf71be7b210de60b899029091100a929c7399b0f4d0ed49468eb8017'
'SKIP')
build() {
cmake -DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_VERSION_STABLE=ON \
-DBUILD_VERSION_DIST_CONTACT="https://aur.archlinux.org/packages/renderdoc" \
-DBUILD_VERSION_DIST_NAME="Arch" \
-DBUILD_VERSION_DIST_VER="${pkgver}" \
-DVULKAN_LAYER_FOLDER="${pkgdir}/etc/vulkan/implicit_layer.d" \
-B"${srcdir}/${pkgname}-${pkgver}"/build \
-H"${srcdir}/${pkgname}-${pkgver}"
cmake --build "${srcdir}/${pkgname}-${pkgver}"/build
}
package() {
cmake --install "${srcdir}/${pkgname}-${pkgver}"/build -v --strip --prefix "$pkgdir/usr"
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/LICENSE.md" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ts=2 sw=2 et:
|