blob: b28e2e5927c7ab0d433448bcfc39c7c5a8dae2f2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>
# Contributor: Hubert Jarosz <marqin.pl+aur at gmail dot com> PGP: 0xFFECF63C1AAB83FF
pkgname=renderdoc-git
pkgver=1.11
pkgrel=2
pkgdesc="OpenGL and Vulkan debugging tool"
arch=(i686 x86_64)
url="https://github.com/baldurk/renderdoc"
license=("MIT")
makedepends=("cmake" "ninja" "python")
depends=("wayland" "libx11" "libxcb" "mesa" "libgl" "qt5-base" "qt5-svg" "qt5-x11extras" "xcb-util-keysyms")
source=("git+https://github.com/baldurk/renderdoc"
"renderdoc.desktop")
sha256sums=('SKIP'
'eab4941dc17fbbdcb9e34a698c3b304d212be54956daeb0c3b1cf5b7f2b00984')
conflicts=('renderdoc')
provides=("renderdoc=${pkgver%+*}")
pkgver() {
cd "${srcdir}"/renderdoc
git describe --always --abbrev=10 HEAD |
sed 's/^v//; s/-/+/; s/-/./'
}
build() {
cmake -DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_VERSION_DIST_CONTACT="https://aur.archlinux.org/packages/renderdoc-git" \
-DBUILD_VERSION_DIST_NAME="Arch" \
-DBUILD_VERSION_DIST_VER="${pkgver}" \
-D ENABLE_WAYLAND=true \
-S renderdoc -B build \
-G Ninja
ninja -C build
}
package() {
DESTDIR="$pkgdir" ninja -C build install
install -Dm644 "${srcdir}"/renderdoc.desktop "$pkgdir/usr/share/applications/renderdoc.desktop"
install -Dm644 "${srcdir}"/renderdoc/docs/imgs/logo.png "$pkgdir/usr/share/icons/renderdoc.png"
}
|