PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: Raidriar <aur.raidriar at pm dot me>
# Contributor: bredo <bredo at bredo dot tech>

_pkgname=renderide
pkgname=$_pkgname-git
pkgver=r3115.1b45f07
pkgrel=1
epoch=0
pkgdesc="A modern Rust + wgpu renderer for Resonite"
arch=('x86_64')
url="https://github.com/DoubleStyx/Renderide"
license=('MIT')
depends=('gstreamer' 'gst-plugins-base-libs' 'zenity')
optdepends=('openxr: VR support')
makedepends=('cargo' 'git' 'sccache')
provides=('renderide')
options=(!lto)
install="renderide.install"
source=("$pkgname::git+https://github.com/DoubleStyx/Renderide" "Identifier.patch" "renderide.desktop")
sha256sums=('SKIP'
            'ca4bc19d7ebba9dea3150f3db90b9193de98d7caf23b2c34a4505c538f23fbc9'
            'ac378d546ceed8ec698601684ae58f92cb131a42aa5186316aa6b99f0e86c907')

pkgver() {
	cd "$pkgname"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

prepare() {
	cd "$pkgname"
	export RUSTUP_TOOLCHAIN=stable
	cargo fetch --locked --target host-tuple
	git apply "$srcdir/Identifier.patch"
}

build() {
	cd "$pkgname"
	export RUSTUP_TOOLCHAIN=stable
	export CARGO_TARGET_DIR=target
	RUSTC_WRAPPER=sccache
	cargo build --frozen --release --features video-textures
}

package() {
	cd "$pkgname"
	install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$_pkgname"
	install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$_pkgname-renderer"
	mkdir -p -m 755 "$pkgdir/usr/share/$_pkgname/"
	cp -r "crates/renderide/assets/models" "$pkgdir/usr/share/$_pkgname/"
	cp -r "target/release/shaders" "$pkgdir/usr/share/$_pkgname/"
	cp -r "target/release/xr" "$pkgdir/usr/share/$_pkgname/"
	chmod -R a=rX,u+w "$pkgdir/usr/share/$_pkgname/"
	install -Dm0755 -t "$pkgdir/usr/share/applications" "$srcdir/renderide.desktop"
	install -Dm0644 LICENSE -t "$pkgdir/usr/share/licenses/$_pkgname/"
}