PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: Donald Carr <d@chaos-reins.com>

_pkgname="reterminatevt"
pkgname="$_pkgname-git"
pkgver=1.2026.06.02.r0.g53f14df
pkgrel=2
pkgdesc="https://www.reddit.com/r/linux/comments/1srbr7m/config_vtn_in_2026/"
url='https://gitlab.freedesktop.org/n3rdopolis/reterminatevt'
license=('GPL2')
arch=('x86_64')

optdepends=(
  'fenrir'
)

depends=(
  'alsa-utils'
  'cage'
  'foot'
  'foot-terminfo'
  'socat'
  'wl-clipboard'
  'kanshi'
  'perl-net-dbus'
  'polkit'
)

makedepends=(
  'cmake'
  'git'
  'meson'
)

provides=("$_pkgname=${pkgver%.g*}")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
    | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  arch-meson "${_meson_args[@]}" "$_pkgsrc" build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs --no-rebuild --suite reterminatevt
}

package() {
  meson install -C build --destdir "$pkgdir"
  install -Dm644 "$_pkgsrc/COPYING.txt" -t "$pkgdir/usr/share/licenses/$pkgname/"
}