summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 74c80ed21901948e4ce2f76d80702187515f2b71 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
# Maintainer: Dobroslaw Kijowski <dobo90_at_gmail.com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Sergey Slipchenko <faergeek@gmail.com>
# Contributor: Themaister <maister@archlinux.us>
# Contributor: lifning <definelightning@gmail.com>

_pkgname=retroarch
pkgname=retroarch-rbp4
pkgver=1.8.5
pkgrel=1
pkgdesc='Reference frontend for the libretro API (Raspberry Pi 4)'
arch=(armv7h)
url=http://www.libretro.com/
license=(GPL)
groups=(libretro)
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}" "${_pkgname}-rbp")
depends=(
  alsa-lib
  flac
  libass.so
  libavcodec.so
  libavformat.so
  libavutil.so
  libfreetype.so
  libswresample.so
  libswscale.so
  libudev.so
  libusb-1.0.so
  libxkbcommon
  mbedtls
  mesa
  miniupnpc
  v4l-utils
)
makedepends=(
  git
)
optdepends=(
  'libretro-overlays: Collection of overlays'
  'libretro-shaders: Collection of shaders'
  'python: retroarch-cg2glsl'
  'retroarch-assets-xmb: XMB menu assets'
)
backup=(etc/retroarch.cfg)
source=(
  git+https://github.com/libretro/RetroArch.git#tag=8bcd74bf42f486c37e243a80e29bc214b2b6b205
  retroarch-config.patch
  service
  sysusers.conf
  tmpfiles.conf
)
sha256sums=(
  SKIP
  7857cff30c45721b66666828ca9edbb2923817c6c64591be3f58fe019277103e
  2e0fd9b160f66ed69630d562ecc0c7db06802d6373305e951f5ffecbdfc93cfb
  d4e4a5ac6c961eafb3edfc28186f75e471dc81e308791d57cfccae4f43de4dae
  e6055a91ca94379f63ff4e8437c085f8f64896a6ce2dd242c36954e48b60d29c
)

pkgver() {
  cd RetroArch

  git describe --tags | sed 's/^v//'
}

prepare() {
  cd RetroArch

  patch -Np1 -i ../retroarch-config.patch
}

build() {
  cd RetroArch

  ./configure \
    --prefix=/usr \
    --disable-al \
    --disable-builtinflac \
    --disable-builtinmbedtls \
    --disable-builtinminiupnpc \
    --disable-builtinzlib \
    --disable-cg \
    --disable-dispmanx \
    --disable-jack \
    --disable-oss \
    --disable-pulse \
    --disable-qt \
    --disable-sdl \
    --disable-sdl2 \
    --disable-vg \
    --disable-wayland \
    --disable-x11 \
    --disable-videocore \
    --disable-vulkan \
    --disable-vulkan_display \
    --enable-kms \
    --enable-opengles \
    --enable-opengles3 \
    --enable-opengl_core \
    --enable-plain_drm
  make
  make -C libretro-common/audio/dsp_filters
  make -C gfx/video_filters
}

package() {
  cd RetroArch

  make DESTDIR="${pkgdir}" install

  install -Dm 644 libretro-common/audio/dsp_filters/*.{dsp,so} -t "${pkgdir}"/usr/lib/retroarch/filters/audio/
  install -Dm 644 gfx/video_filters/*.{filt,so} -t "${pkgdir}"/usr/lib/retroarch/filters/video/

  install -Dm 644 "${srcdir}"/service "${pkgdir}"/usr/lib/systemd/system/retroarch.service
  install -Dm 644 "${srcdir}"/sysusers.conf "${pkgdir}"/usr/lib/sysusers.d/retroarch.conf
  install -Dm 644 "${srcdir}"/tmpfiles.conf "${pkgdir}"/usr/lib/tmpfiles.d/retroarch.conf
}

# vim: ts=2 sw=2 et: