blob: d91283763e488de9e4617da3350621a49944e492 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
# Maintainer: 3ED <krzysztof1987 _at_ gmail _dot_ com>
pkgbase=rhythmcat
pkgname=rhythmcat
true && pkgname=(rhythmcat rhythmcat-plugins rhythmcat-plugins-extra)
pkgver=1.0.1.1
pkgrel=2
_pkgname=RhythmCat
_pkgver=1.0.1-1
pkgdesc="A Audio Player in GTK3 with plug-in support"
arch=('i686' 'x86_64')
url="https://code.google.com/p/rhythmcat/"
license=('GPL')
makedepends=('gtk-doc' 'gtksourceview3' 'gendesk')
depends=('gtk3' 'gstreamer0.10-base-plugins' 'gstreamer0.10-good-plugins' 'dbus-glib')
source=(https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/${pkgname}/${_pkgname}-${_pkgver}_Source.tar.bz2)
sha256sums=('baac929234d328392ebe2761faea6e9c0efa6bb49c3b77e836771ebd81e515f9')
_plugins_base=(desktop-lyric lyric-show music-locator notify)
_plugins_extra=(lyric-crawler lyric-editor tageditor)
prepare() {
gendesk -n -f \
--pkgname="${_pkgname}" \
--pkgdesc="${pkgdesc}" \
--genericname="RhythmCat Music Player" \
--categories="AudioVideo;Player;GTK" \
--mimetypes='application/x-ogg;application/ogg;audio/x-vorbis+ogg;audio/x-scpls;audio/x-mp3;audio/x-mpeg;audio/mpeg;audio/x-mpegurl;audio/x-flac'
}
build() {
cd ${_pkgname}-${_pkgver}
./configure \
--prefix=/usr \
--enable-gtk3
make
for i in "${_plugins_base[@]}"; do
make --makefile=Makefile3 -C plugins/base/$i
done
for i in "${_plugins_extra[@]}"; do
make --makefile=Makefile3 -C plugins/extra/$i
done
}
check() {
cd ${_pkgname}-${_pkgver}
make check
}
package_rhythmcat() {
pkgdesc="A Audio Player in GTK3"
optdepends=('gstreamer0.10-ugly-plugins: Extra media codecs'
'gstreamer0.10-bad-plugins: Extra media codecs'
'gstreamer0.10-ffmpeg: Extra media codecs'
'rhythmcat-plugins: Base plugins'
'rhythmcat-plugins-extra: Extra plugins')
install -dm755 "$pkgdir"/usr/share/{applications,pixmaps}/
install -m 644 ${_pkgname}.desktop "$pkgdir/usr/share/applications/"
cd ${_pkgname}-${_pkgver}
make DESTDIR="$pkgdir/" install
ln -s ../RhythmCat/images/RhythmCat_128x128.PNG \
"$pkgdir"/usr/share/pixmaps/${_pkgname}.png
}
package_rhythmcat-plugins() {
pkgdesc="Base plugins for RhythmCat"
depends=(rhythmcat gtksourceview3)
cd ${_pkgname}-${_pkgver}
for i in "${_plugins_base[@]}"; do
make INSTALL_DIR="$pkgdir/usr/share/RhythmCat/plugins/$i" -C plugins/base/$i install
done
}
package_rhythmcat-plugins-extra() {
pkgdesc="Extra plugins for RhythmCat"
depends=(rhythmcat)
cd $srcdir/${_pkgname}-${_pkgver}
for i in "${_plugins_extra[@]}"; do
make INSTALL_DIR="$pkgdir/usr/share/RhythmCat/plugins/$i" -C plugins/extra/$i install
done
}
# AUR:
pkgdesc="A Audio Player in GTK3 with plug-in support"
depends=('gtk3' 'gstreamer0.10-base-plugins' 'gstreamer0.10-good-plugins' 'dbus-glib')
# vim:set ts=2 sw=2 et:
|