blob: 05c5170abb383c7798314931951b93d5b81dba99 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Aanok (aanok.aur@gmail.com)
# Contributor: Parker Ellertson (rasputin-machine) <parker@rasputinmachine.com>
# Contributor: therealfarfetchd
pkgname='ripcord'
pkgver=0.4.18
pkgrel=1
pkgdesc='Qt-based Discord and Slack client'
arch=('x86_64')
depends=('harfbuzz' 'libgl')
url='https://cancel.fm/ripcord/'
license=('custom')
validpgpkeys=('ABBAD1CB484F53024CF5868B69332F9203F21F5C')
_file="Ripcord-$pkgver-x86_64.AppImage"
source=("https://cancel.fm/dl/$_file"{,.asc})
sha256sums=('97106aa913266e2b80c8cf049dae986af09c09b2afad92e129741083f02ddba6' 'SKIP')
# !! AppImage is emptied if symbols are stripped away !!
# But beyond that, the program is deployed with symbols on purpose
options=('!strip')
# AppImage is already compressed, no reason to compress it again
# Kept as reminder
#PKGEXT='.pkg.tar'
prepare() {
# Extract AppImage contents so we install bypassing every and all AppImage
# desktop integration/deployment mechanisms
chmod +x "$_file"
"./$_file" --appimage-extract &>/dev/null
}
package() {
# directories
install -d "$pkgdir"/usr/bin/
install -d "$pkgdir"/usr/lib/ripcord/
install -d "$pkgdir"/usr/share/applications/
install -d "$pkgdir"/usr/share/icons/
install -d "$pkgdir"/usr/share/licenses/"$pkgname"
# icon
install -m644 squashfs-root/Ripcord_Icon.png "$pkgdir"/usr/share/icons/
# .desktop file
sed -i 's/Exec=Ripcord/Exec=\/usr\/bin\/ripcord/' squashfs-root/Ripcord.desktop
install -m644 squashfs-root/Ripcord.desktop "$pkgdir"/usr/share/applications
# license
sed -i '1s/^/Copyright 2016 - 2019 Acyclic Systems LLC All Rights Reserved\n\n/' squashfs-root/additional_license_information.txt
install -m644 squashfs-root/additional_license_information.txt "$pkgdir"/usr/share/licenses/"$pkgname"/LICENSE
# application
chmod 755 -R squashfs-root/lib squashfs-root/plugins squashfs-root/plugins/*
mv squashfs-root/* "$pkgdir"/usr/lib/ripcord/
ln -s /usr/lib/ripcord/Ripcord "$pkgdir"/usr/bin/ripcord
}
|