blob: 6a4ab40599fbbc7b412947c76e05100cd48e09fe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Aanok (aanok.aur@gmail.com)
# Contributor: Parker Ellertson (rasputin-machine) <parkerllertson airmail cc>
# Contributor: therealfarfetchd
pkgname='ripcord'
pkgver=0.3.1
pkgrel=1
pkgdesc='Qt-based Discord and Slack client'
arch=('x86_64')
url='https://cancel.fm/ripcord/'
license=('custom')
validpgpkeys=('ABBAD1CB484F53024CF5868B69332F9203F21F5C')
_file="Ripcord-${pkgver}-${CARCH}.AppImage"
source=(
"https://cancel.fm/dl/$_file"
"https://cancel.fm/dl/$_file.asc"
)
sha256sums=(
'5510196fbc040ee5e95dfd4685ef0ec97990dbea87a0b142edb972ed83115d71'
'SKIP'
)
# !! AppImage is emptied if symbols are stripped away !!
options=('!strip')
PKGEXT='.pkg.tar'
prepare() {
# we extract so we can install the icon and .desktop files
chmod +x "$_file"
"./$_file" --appimage-extract &>/dev/null
}
package() {
install -d "$pkgdir"/usr/bin/
install -d "$pkgdir"/opt/ripcord/
install -d "$pkgdir"/usr/share/applications/
install -d "$pkgdir"/usr/share/icons/
install -m644 squashfs-root/Ripcord_Icon.png "$pkgdir"/usr/share/icons/
sed -i 's/Exec=Ripcord/Exec=\/usr\/bin\/ripcord/' squashfs-root/Ripcord.desktop
install -m644 squashfs-root/Ripcord.desktop "$pkgdir"/usr/share/applications
install "$_file" "$pkgdir"/opt/ripcord
ln -s /opt/ripcord/"$_file" "$pkgdir"/usr/bin/ripcord
}
|