blob: 2e306382c8346e97799c70635d91d707d8fd9c2f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: xiretza <xiretza+aur@xiretza.xyz>
# Contributor: Emil Renner Berthing <aur@esmil.dk>
_target=riscv64-unknown-elf
pkgname=$_target-picolibc
pkgver=1.7
pkgrel=1
pkgdesc='Fork of newlib with stdio bits from avrlibc'
conflicts=("$_target-newlib")
arch=('i686' 'x86_64')
url='https://github.com/picolibc/picolibc'
license=('BSD')
makedepends=("$_target-gcc" 'meson')
source=("picolibc-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
sha256sums=('5d4e43e954fc0823380ddf3a6397a8ba71e6710fdf58f3fa46401f3f3485818c')
options=(!strip !buildflags)
build() {
meson \
--prefix="/usr/$_target" \
--buildtype=plain \
--cross-file "picolibc-$pkgver/scripts/cross-${_target}.txt" \
"picolibc-$pkgver" build
meson compile -C build
}
package() {
DESTDIR="$pkgdir" meson install -C build
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" "$srcdir/picolibc-$pkgver/COPYING."{GPL2,NEWLIB,picolibc}
}
# vim: set ts=2 sw=2 et:
|