PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Jörn Hofmann <joernhofmann@web.de>
pkgbase=rkcfgtool-git
pkgname=rkcfgtool-git
pkgver=1.0.0.r0.g414bf46
pkgrel=1
pkgdesc="Command line utility for Rockchip RKDevTool configuration files"
arch=('any')
depends=()
makedepends=('git' 'make' 'gcc')
checkdepends=('diffutils' 'grep' 'xxd')
url="https://github.com/guoh27/rkcfgtool"
license=('MIT')
provides=(${pkgbase%-git})
conflicts=(${pkgbase%-git})
source=(
    "${pkgname}::git+${url}.git"
)
sha256sums=(
    "SKIP"
)

pkgver() {
  cd "$pkgname"
  git describe --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    git -C "${srcdir}/${pkgname}" clean -dfx
}

build() {
    cd "${srcdir}/${pkgname}"
    make
}

check() {
    cd "${srcdir}/${pkgname}"
    chmod +x test.sh
    ./test.sh
}

package() {
    cd "${srcdir}/${pkgname}"
    make DESTDIR="${pkgdir}" PREFIX=/usr install
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}