blob: 1f42eb9ffdbdb02737f5140d776a2ffde7eba705 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Ismael González Valverde <ismgonval@gmail.com>
pkgname=rnr
pkgver=0.5.0
pkgrel=1
pkgdesc='A CLI tool to rename files and directories that supports regex.'
provides=('rnr')
makedepends=('rust')
arch=('x86_64')
url='https://github.com/ismaelgv/rnr'
license=('MIT')
source=("$pkgname-$pkgver.tar.gz::https://github.com/ismaelgv/rnr/archive/v$pkgver/v$pkgver.tar.gz")
md5sums=('9f41564ebffcd6ecf401aad6ec04dd22')
build () {
cd ${pkgname}-$pkgver
export CARGO_TARGET_DIR=target
cargo build --release --locked --all-features
}
check() {
cd ${pkgname}-$pkgver
cargo test --release --locked
}
package() {
cd ${pkgname}-$pkgver
local target_dir="target/release"
# Binary
install -Dm 755 "${target_dir}/${pkgname}" -t "${pkgdir}/usr/bin"
# Man files
local man_dir='./man1'
mkdir -p "${man_dir}"
cp "${target_dir}/build/${pkgname}"-*/out/"${pkgname}"*.1 "${man_dir}"
install -Dm644 "${man_dir}/${pkgname}"*.1 -t "$pkgdir/usr/share/man/man1"
# Completion files
local completion_dir='./completion'
mkdir -p "${completion_dir}"
cp "${target_dir}/build/${pkgname}"-*/out/"_${pkgname}" "${completion_dir}"
cp "${target_dir}/build/${pkgname}"-*/out/"${pkgname}.bash" "${completion_dir}"
cp "${target_dir}/build/${pkgname}"-*/out/"${pkgname}.fish" "${completion_dir}"
install -Dm644 "${completion_dir}/_${pkgname}" "$pkgdir/usr/share/zsh/site-functions/_${pkgname}"
install -Dm644 "${completion_dir}/${pkgname}.bash" \
"$pkgdir/usr/share/bash-completion/completions/${pkgname}"
install -Dm644 "${completion_dir}/${pkgname}.fish" \
"$pkgdir/usr/share/fish/completions/${pkgname}.fish"
# Documentation
install -Dm644 "README.md" "$pkgdir/usr/share/doc/${pkgname}/README.md"
# License files
install -Dm644 LICENSE \
"$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}
|