blob: b6502c0d92c56909080718f59efc873f95195d99 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Maintainer: Stephan Springer <buzo+arch@Lini.de>
# Contributor: ml
# Contributor: sum01 <sum01@protonmail.com>
pkgname=rocketchat-desktop
pkgver=3.9.0
pkgrel=1
pkgdesc='Rocket.Chat Native Cross-Platform Desktop Application via Electron'
arch=('any')
url='https://github.com/RocketChat/Rocket.Chat.Electron'
license=('MIT')
_electron=electron21
depends=("$_electron" 'nodejs' 'libvips')
makedepends=('node-gyp' 'yarn' 'asar')
install=rocketchat-desktop.install
changelog=CHANGELOG.md
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver/$pkgname-$pkgver.tar.gz"
rocketchat-desktop
rocketchat-desktop.desktop)
sha256sums=('42ebea08de48ea6ed668f2e5d9d6c8f7d25f9070c874a1376be2011ff4385e6f'
'5fe8f552b4ac1917a1bb08e86f957e9b892220a2aab59b88e8256e2e092e1b1c'
'31fae4f98a61a774f84030fd43d2ef92c7633740dc5aa55967a21d0e29ea621a')
# validpgpkeys=('9EA06BE6FD613A03') # Tasso Evangelista
prepare() {
_ver="$(</usr/lib/"$_electron"/version)"
cd "Rocket.Chat.Electron-$pkgver"
yarn install
yarn upgrade "electron@$_ver"
}
build() {
cd "Rocket.Chat.Electron-$pkgver"
local i686=ia32 x86_64=x64
export NODE_ENV=production
export NODE_OPTIONS='--openssl-legacy-provider'
yarn build
yarn run electron-builder --linux --"${!CARCH}" --dir \
-c.electronDist=/usr/lib/"$_electron" \
-c.electronVersion="$_ver"
}
package() {
local i686=linux-ia32-unpacked x86_64=linux-unpacked aarch64=linux-arm64-unpacked
install -Dm644 -t "${pkgdir}/usr/share/applications" "${pkgname}.desktop"
install -D -t "${pkgdir}/usr/bin" "$pkgname"
cd "Rocket.Chat.Electron-$pkgver"
install -Dm644 "build/icons/512x512.png" "$pkgdir/usr/share/icons/hicolor/512x512/apps/$pkgname.png"
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
install -d "$pkgdir/usr/lib/$pkgname/"
asar e "dist/${!CARCH}/resources/app.asar" "$pkgdir/usr/lib/$pkgname/"
}
|