blob: cad5156dbf371503963597a8b7d736d065982a42 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
pkgname=rockpass
pkgver=0.3.0
pkgrel=1
pkgdesc='A small and ultrasecure Lesspass database server written in Rust'
arch=('arm' 'armv6h' 'armv7h' 'aarch64' 'i686' 'x86_64')
url='https://github.com/ogarcia/rockpass'
license=('GPL3')
depends=('sqlite')
makedepends=('rustup')
backup=("etc/${pkgname}.conf")
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/ogarcia/${pkgname}/archive/${pkgver}.tar.gz"
"${pkgname}.conf"
"${pkgname}.service")
sha256sums=('9bf26a771768a0e0585cee3e56b27aa2df78c918b10c627d2b360cceebea0aec'
'4b3ccc143948592202993b7879ef6c422fbab4d8580696884a272f175c07e4ba'
'5175d4d689c8f9b63a4d1409ab48d4ec91e37120cec8c4be1f8ba871363be424')
prepare() {
cd "${pkgbase}-${pkgver}"
rustup override set nightly
}
build() {
cd "${pkgbase}-${pkgver}"
cargo build --release --locked --all-features --target-dir=target
}
package() {
# binary
install -Dm755 "${srcdir}/${pkgbase}-${pkgver}/target/release/${pkgname}" \
"${pkgdir}/usr/bin/${pkgname}"
# conf
install -Dm644 "${srcdir}/${pkgname}.conf" "${pkgdir}/etc/${pkgname}.conf"
# service
install -Dm644 "${srcdir}/${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
}
|