PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Marvin Kreis <MarvinKreis@web.de>

pkgname=rofi-file-browser-extended-git
pkgver=1.0.1
pkgrel=1
pkgdesc="A plugin to use rofi as a file browser"
arch=("x86_64")
url="https://github.com/marvinkreis/${pkgname%-git}"
license=("MIT")
depends=("rofi" "gtk3")
makedepends=("git" "cmake")
provides=("rofi-file-browser-extended")
replaces=("rofi-file_browser-extended")
source=("git+https://github.com/marvinkreis/${pkgname%-git}.git")
md5sums=("SKIP")

pkgver() {
    cd "${srcdir}/${pkgname%-git}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "${srcdir}/${pkgname%-git}"
    git submodule init
    git submodule update
}

build() {
    cd "${srcdir}/${pkgname%-git}"
    cmake .
    make
}

package() {
    cd "${srcdir}/${pkgname%-git}"
    make DESTDIR="${pkgdir}" PREFIX=/usr install
    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}