summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 742700919d6ad6f63c0a35c8e7780d6f465047a6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
# Maintainer: Benjamin Chr├ętien <chretien+aur [at] lirmm [dot] fr>
# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
# Contributor: Rasi <rasi@xssn.at>
# Contributor: Sean Pringle <sean.pringle@gmail.com>
# Contributor: SanskritFritz (gmail)
# Contributor: Ruben De Smet <me at rubdos dot be>

pkgname=rofi-wayland-git
_gitname=rofi
pkgver=1.3.1.r384.g3a29d3ec
pkgrel=2
pkgdesc="A window switcher, run dialog and dmenu replacement"
arch=('i686' 'x86_64')
url="https://davedavenport.github.io/rofi/"
license=('MIT')
depends=(freetype2 libxdg-basedir pango xcb-util-xrm wayland-wall)
optdepends=('sway: use as application runner'
            'wlc-wall-injector: injects wall wayland protocol in wlc based compositors'
            'orbment: use as application runner')
makedepends=('git' 'wayland' 'libxkbcommon' 'xcb-util-wm')
provides=('rofi')
conflicts=('rofi')
source=("git+https://github.com/DaveDavenport/rofi#branch=wip/wayland")
md5sums=('SKIP')

pkgver() {
  cd "$_gitname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/$_gitname"
  git submodule update --init

  # By default, installs pkg-config file in /usr/local/share/pkgconfig
  # instead of /usr/share/pkgconfig.
  export PKG_CONFIG_PATH=/usr/share/pkgconfig:/usr/local/share/pkgconfig
  autoreconf --install

  # Default compiler = clang, which can be a problem if using hardening-wrapper
  CC=gcc ./configure --prefix=/usr --with-display-backend=wayland
}

build() {
  cd "$srcdir/$_gitname"
  make
}

package() {
  cd "$srcdir/$_gitname"
  make install install-man DESTDIR="$pkgdir"

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/rofi-wayland-git/COPYING"
  install -dm755 "$pkgdir/usr/share/doc/rofi/examples"
  install -Dm755 Examples/*.sh "$pkgdir/usr/share/doc/rofi/examples"
}