PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155

# Maintainer: Darvin Delgado <dnmodder at gmail dot com>

pkgname=('rom-properties' 'rom-properties-gtk' 'rom-properties-kde')
pkgbase=rom-properties
pkgdesc="Shell extension for displaying ROM and disc image metadata in file managers"
pkgver=2.8
pkgrel=1
arch=('x86_64')
url='https://github.com/GerbilSoft/rom-properties'
license=('GPL-2.0-or-later')
makedepends=(
    'cairo'
    'cmake'
    'extra-cmake-modules'
    'fmt'
    'gdk-pixbuf2'
    'gettext'
    'glib2-devel'
    'gsound'
    'gtk3'
    'gtk4'
    'kcrash'
    'kio'
    'kfilemetadata'
    'kwidgetsaddons'
    'libnautilus-extension'
    'pkgconf'
    'pugixml'
    'python'
    'qt5-base'
    'qt6-base'
    'qt6-tools'
)
source=(
    "$pkgbase-$pkgver.tar.gz::https://github.com/GerbilSoft/rom-properties/archive/v$pkgver.tar.gz"
)
sha256sums=(
    'c9eccc8d57751878c115073cd3b61ae6b7a0380bf5a07e229bc4d8683675aa71'
)
options=(!debug)


build() {
    cd "$pkgbase-$pkgver"

    mkdir -p build && cd build

    cmake .. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBEXECDIR=lib/$pkgname \
    -DCMAKE_BUILD_TYPE=Release \
    -DSPLIT_DEBUG=OFF \
    -DBUILD_KDE4=OFF \
    -DBUILD_KF5=OFF \
    -DBUILD_KF6=ON \
    -DBUILD_GTK3=ON \
    -DBUILD_GTK4=ON \
    -DENABLE_ZSTD=ON \
    -DENABLE_LZ4=ON \
    -DENABLE_LZO=ON \
    -DENABLE_XML=ON \
    -DUSE_INTERNAL_ZSTD=OFF \
    -DUSE_INTERNAL_LZ4=OFF \
    -DUSE_INTERNAL_LZO=OFF \
    -DUSE_INTERNAL_XML=OFF \
    -DUSE_INTERNAL_FMT=OFF \
    -Wno-dev

    make
}


package_rom-properties() {
    depends=(
        'curl'
        'fmt'
        'glibc'
        'libgcc'
        'libgomp'
        'libjpeg-turbo'
        'libpng'
        'libseccomp'
        'libstdc++'
        'nettle'
        'pugixml'
        'zlib'
        'zstd'
    )
    optdepends=(
        'libwebp: WebP image decoding support (for Android APK packages)'
        'lz4: For PSP CISOv2 and ZISO compressed disc decompression'
        'lzo: For PSP JISO compressed disc decompression'
        'rom-properties-gtk: GTK extensions for file managers (Nautilus, Desktop Search, Caja, Nemo, Thunar)'
        'rom-properties-kde: Qt6/KF6 plugins for Dolphin and KFileMetaData'
    )

    cd "$pkgbase-$pkgver/build"

    DESTDIR="$pkgdir" make install

    rm $pkgdir/usr/bin/rp-thumbnailer-dbus
    rm -rf $pkgdir/usr/lib/caja
    rm -rf $pkgdir/usr/lib/nautilus
    rm -rf $pkgdir/usr/lib/nemo
    rm -rf $pkgdir/usr/lib/qt6
    rm -rf $pkgdir/usr/lib/thunarx-3
    rm -rf $pkgdir/usr/lib/localsearch-3.0
    rm -rf $pkgdir/usr/share/caja
    rm -rf $pkgdir/usr/share/dbus-1
    rm -rf $pkgdir/usr/share/kio
    rm -rf $pkgdir/usr/share/thumbnailers
    rm -rf $pkgdir/usr/share/localsearch3
}


package_rom-properties-gtk() {
    pkgdesc="Nautilus and other GTK-based file manager extensions for rom-properties"
    depends=(
        'cairo'
        'fmt'
        'glib2'
        'glibc'
        'gsound'
        'gtk3'
        'gtk4'
        'libgcc'
        'libstdc++'
        'pango'
        'rom-properties'
    )

    cd "$pkgbase-$pkgver/build/src/gtk"

    DESTDIR="$pkgdir" make install
}

package_rom-properties-kde() {
    pkgdesc="Dolphin, KFileMetaData, and KF6 plugins for rom-properties"
    depends=(
        'fmt'
        'glibc'
        'kcoreaddons'
        'kfilemetadata'
        'kio'
        'kwidgetsaddons'
        'libgcc'
        'libstdc++'
        'qt6-base'
        'rom-properties'
    )

    cd "$pkgbase-$pkgver/build/src/kde"

    DESTDIR="$pkgdir" make install
}