blob: bc9d228e14b92ec0cef6234a8a83244e47bdb056 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# Maintainer: Konstantin Gizdov < arch at kge dot pw >
# Contributor: Frank Siegert < frank.siegert at googlemail dot com >
# Contributor: Scott Lawrence < bytbox at gmail dot com >
# Contributor: Thomas Dziedzic < gostrc at gmail dot com >
# Contributor: Sebastian Voecking < voeck at web dot de >
pkgname=root-extra
_pkgname=root
pkgver=6.10.00
pkgrel=1
provides=('root' 'root-extra')
conflicts=('root')
pkgdesc='C++ data analysis framework and interpreter from CERN with extra features enabled.'
arch=('i686' 'x86_64')
url='http://root.cern.ch'
license=('LGPL2.1')
makedepends=('cmake')
depends=('cfitsio'
'fftw'
'ftgl'
'gl2ps'
'glew'
'graphviz'
'gsl'
'hicolor-icon-theme'
'intel-tbb'
'libafterimage'
'libiodbc'
'libmariadbclient'
'postgresql-libs'
'pythia>=8.2.23-3'
'python'
'sqlite'
'tex-gyre-fonts' # solve the pixelized font problem as per Arch Wiki
'unixodbc'
'unuran'
'xmlrpc-c'
'xrootd>=4.6.0-2')
optdepends=('blas: Optional extensions to TMVA'
'gcc-fortran: Enable the Fortran components of ROOT'
'tcsh: Legacy CSH support')
options=('!emptydirs')
install=root-extra.install
source=("https://root.cern.ch/download/root_v${pkgver}.source.tar.gz"
'root-extra.install'
'root.sh'
'root.xml'
'rootd'
'settings.cmake')
sha256sums=('5753eede44dcd1898804fb0127e4a3e9c1acf6ac03ae5e5eec7aace0f065b8e7'
'f1796729b0403026382bca43329692f5356c8ec46fc2c09f799a8b3d12d49a6f'
'9d1f8e7ad923cb5450386edbbce085d258653c0160419cdd6ff154542cc32bd7'
'50c08191a5b281a39aa05ace4feb8d5405707b4c54a5dcba061f954649c38cb0'
'3c45b03761d5254142710b7004af0077f18efece7c95511910140d0542c8de8a'
'40503aebd8a0ab5380a24d69145cf7d93d483d4d9330e4c23fb04e55c9ed2caf')
prepare() {
cd "${_pkgname}-${pkgver}"
msg2 'Adjusting to Python3...'
2to3 -w etc/dictpch/makepch.py 2>&1 > /dev/null
}
build() {
mkdir -p "${srcdir}/build"
cd "${srcdir}/build"
msg2 'Configuring...'
CFLAGS="${CFLAGS} -pthread" \
CXXFLAGS="${CXXFLAGS} -pthread" \
LDFLAGS="${LDFLAGS} -pthread -Wl,--no-undefined" \
cmake -C "${srcdir}/settings.cmake" "${srcdir}/${_pkgname}-${pkgver}"
msg2 'Compiling...'
make ${MAKEFLAGS}
}
package() {
cd "${srcdir}/build"
msg2 'Installing...'
make DESTDIR="${pkgdir}" install
install -D "${srcdir}/root.sh" \
"${pkgdir}/etc/profile.d/root.sh"
install -D "${srcdir}/rootd" \
"${pkgdir}/etc/rc.d/rootd"
install -D -m644 "${srcdir}/root.xml" \
"${pkgdir}/usr/share/mime/packages/root.xml"
install -D -m644 "${srcdir}/${_pkgname}-${pkgver}/build/package/debian/root-system-bin.desktop.in" \
"${pkgdir}/usr/share/applications/root-system-bin.desktop"
# replace @prefix@ with /usr for the desktop
sed -e 's_@prefix@_/usr_' -i "${pkgdir}/usr/share/applications/root-system-bin.desktop"
# fix python env call
sed -e 's/@python@/python/' -i "${pkgdir}/usr/lib/root/cmdLineUtils.py"
install -D -m644 "${srcdir}/${_pkgname}-${pkgver}/build/package/debian/root-system-bin.png" \
"${pkgdir}/usr/share/icons/hicolor/48x48/apps/root-system-bin.png"
msg2 'Updating system config...'
# use a file that pacman can track instead of adding directly to ld.so.conf
install -d "${pkgdir}/etc/ld.so.conf.d"
echo '/usr/lib/root' > "${pkgdir}/etc/ld.so.conf.d/root.conf"
msg2 'Cleaning up...'
rm -rf "${pkgdir}/etc/root/daemons"
}
|