PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Björn Feber <bfeber@protonmail.com>
pkgname=ross-applicationlauncher-git
pkgver=r51.8ed4191
pkgrel=1
pkgdesc="Application Launcher for the ROSS Shell"
arch=('x86_64')
url="https://github.com/rosssoftware/Shell/tree/master/ApplicationLauncher"
license=('GPL3')
depends=('libqtxdg')
optdepends=()
makedepends=('cmake' 'qt5-tools' 'git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}::git+https://github.com/rosssoftware/Shell.git")
sha256sums=('SKIP')

pkgver() {
	cd "${pkgname%-git}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	mkdir -p "${pkgname%-git}/ApplicationLauncher/build"
}

build() {
	cd "${pkgname%-git}/ApplicationLauncher/build"
	cmake \
		.. \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_BUILD_TYPE=Release
	make
}

package() {
	cd "${pkgname%-git}/ApplicationLauncher/build"
	make DESTDIR="$pkgdir/" install
}