PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Sanpi <sanpi+aur@homecomputing.fr>
pkgname=routino-svn
pkgver=r1832
pkgrel=1
pkgdesc='Router for OpenStreetMap Data'
arch=('x86_64')
url='http://www.routino.org/'
license=('AGPL3')
depends=('zlib' 'bzip2')
makedepends=('make' 'subversion')
conflicts=('routino')
provides=('routino')
source=("$pkgname::svn+http://routino.org/svn/trunk/")
sha256sums=('SKIP')

pkgver() {
    cd "$pkgname"

    local ver="$(svnversion)"
    printf "r%s" "${ver//[[:alpha:]]}"
}

prepare() {
    cd "$pkgname"

    sed -i 's|prefix=/usr/local|prefix=/usr|' Makefile.conf
}

build() {
    if echo $MAKEFLAGS | grep  -q -- '-j[2-9]'
    then
        error "Routino parallele compilation failed. Please unset -j make flag and relaunch the build."
        plain "$(gettext "Aborting...")"
        exit 1
    fi

    cd "$pkgname"

    make
}

package() {
    cd "$pkgname"

    make DESTDIR="${pkgdir}" install
    mv "${pkgdir}/usr/doc" "${pkgdir}/usr/share/"
}