blob: 952c29177f01ad44c1ee668686927dce76c00fd5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
pkgname=rsdkv4
pkgver=1.3.2
pkgrel=1
pkgdesc="Complete decompilation of Sonic 1 & Sonic 2 (2013) & Retro Engine (v4)"
arch=(x86_64)
url="https://github.com/Rubberduckycooly/Sonic-1-2-2013-Decompilation"
license=(custom)
depends=(glibc gcc-libs sdl2 glew libvorbis libglvnd)
makedepends=(git cmake)
source=("rsdkv4::git+https://github.com/Rubberduckycooly/Sonic-1-2-2013-Decompilation.git#tag=${pkgver}"
"git+https://github.com/nothings/stb.git"
"git+https://github.com/leethomason/tinyxml2.git"
"git+https://github.com/chriskohlhoff/asio.git")
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP')
prepare() {
cd rsdkv4
git submodule init
git config submodule.dependencies/all/stb-image.url "${srcdir}/stb"
git config submodule.dependencies/all/tinyxml2.url "${srcdir}/tinyxml2"
git config submodule.flatpak/shared-modules.update none
git config submodule.dependencies/all/asio.url "${srcdir}/asio"
git -c protocol.file.allow=always submodule update
}
build() {
cmake -B build -S "rsdkv4" -Wno-dev \
-DCMAKE_BUILD_TYPE=RelWithDebInfo \
-DCMAKE_INSTALL_PREFIX=/usr
cmake --build build
}
package() {
#DESTDIR="$pkgdir" cmake --install build
install -D build/RSDKv4 -t "${pkgdir}/usr/bin"
ln -s /usr/bin/RSDKv4 "${pkgdir}/usr/bin/rsdkv4"
install -D rsdkv4/LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|