blob: 6b37b39f4ea1cc6b7d2c2fdcf07056b79c0800b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Michael Duell <michael.duell@rub.de> PGP-Key: 5566FF77 Fingerprint FF8C D50E 66E9 5491 F30C B75E F32C 939C 5566 FF77
pkgname=rtl-sdr-git
pkgrel=1
pkgver=v0.5.3.r17.g18bf269
epoch=1
pkgdesc="Tuner for DVB-T sticks based on the Realtek RTL2832U, which can be used as a cheap SDR, since the chip allows transferring the raw I/Q samples to the host."
arch=('i686' 'x86_64' 'aarch64')
url="http://sdr.osmocom.org/trac/wiki/rtl-sdr"
license=('GPL')
depends=('libusb>=1.0')
makedepends=('git' 'cmake')
provides=('rtl-sdr')
source=('rtl-sdr::git://git.osmocom.org/rtl-sdr.git')
sha384sums=('SKIP')
pkgver() {
cd "${srcdir}/rtl-sdr"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${srcdir}/rtl-sdr"
mkdir -p build
cd build
cmake -DCMAKE_INSTALL_PREFIX:PATH=/usr -DDETACH_KERNEL_DRIVER=ON -Wno-dev ../
make
}
package() {
cd "${srcdir}/rtl-sdr/build/"
make DESTDIR="${pkgdir}" install
install -D -m644 "${srcdir}/rtl-sdr/rtl-sdr.rules" "${pkgdir}/usr/lib/udev/rules.d/10-rtl-sdr.rules"
}
# vim:set ts=2 sw=2 et:
|