PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Silvan Gümüşdere <silvan@trollbox.org>

pkgname=rtl_icecast-git
pkgver=r19.6cc4023
pkgrel=1
pkgdesc="RTL-SDR Icecast streaming client"
arch=(
    'x86_64'
    'armv7h'
    'aarch64'
)
url="https://github.com/j0uni/rtl_icecast"
license=('MIT')
depends=(
    'lame'
    'libshout'
    'liquid-dsp'
    'rtl-sdr'
)
makedepends=('git')
provides=('rtl_icecast')
source=(
    "$pkgname::git+$url.git"
    "rtl-icecast.service"
)
sha256sums=(
    'SKIP'
    '863bf13db405e4637ee377136a9ec1dd887849a06229543a347ddb0a30b6295c'
)

pkgver() {
    cd "$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
    cd "$pkgname"
    make
}

package() {
    cd "$pkgname"
    install -Dm755 build/rtl_icecast "$pkgdir/usr/bin/rtl_icecast"
    install -Dm644 config.ini.example "$pkgdir/etc/rtl_icecast/config.ini"
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    install -Dm644 ../rtl-icecast.service "$pkgdir/usr/lib/systemd/system/rtl-icecast.service"
}