blob: ce3127b6b904a3161a11cf9336036e8837c5256d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Nikos Toutountzoglou <nikos dot toutou at protonmail dot com>
pkgname=rtpengine-kernel-dkms
pkgver=12.5.1.5
pkgrel=1
pkgdesc='Kernel module for rtpengine media proxy'
url="https://github.com/sipwise/rtpengine"
license=('GPL-3.0-or-later')
arch=('x86_64')
depends=('dkms')
optdepends=('linux-headers: build modules against the Arch kernel'
'linux-lts-headers: build modules against the LTS kernel'
'linux-zen-headers: build modules against the ZEN kernel'
'linux-hardened-headers: build modules against the HARDENED kernel')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/sipwise/rtpengine/archive/refs/tags/mr${pkgver}.tar.gz")
sha256sums=('b25c98268f39209b95f1cb699760191e165051750c9c3e5d1f51be381213852f')
prepare() {
cd rtpengine-mr${pkgver}
# Set version
sed -e "s|#MODULE_VERSION#|$pkgver|" -e "s|ngcp-||" debian/ngcp-rtpengine-kernel-dkms.dkms >dkms.conf
# Insert patches below this line
}
package() {
cd rtpengine-mr${pkgver}
install -Dm644 -t "${pkgdir}/usr/src/rtpengine-${pkgver}" dkms.conf kernel-module/{Makefile,*{.inc,.c,.h}}
# Automatic module loading during boot
install -Dm644 kernel-module/xt_RTPENGINE.modules.load.d "${pkgdir}/etc/modules-load.d/${pkgname}.conf"
}
# vim:set ts=2 sw=2 et:
|