blob: 63819d2f23f00e2b50a4a7575fba686f97388684 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
_gemname=async-io
pkgname=ruby-${_gemname}
pkgver=1.30.2
pkgrel=1
pkgdesc='Provides support for asynchonous TCP, UDP, UNIX and SSL sockets'
url='https://github.com/socketry/async-io'
arch=('any')
license=('MIT')
depends=('ruby' 'ruby-async')
makedepends=('ruby-rdoc')
options=('!emptydirs')
source=(https://github.com/socketry/async-io/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha256sums=('698b9c28b4090bd9f592e1539b62b0c8bac3ce4e92964991f4cf65fbc26fe628')
sha512sums=('8df24402fc5456c18c92b12f4c637ac95ce22a5531e367e30e09eb3e292f621c8bcfbb17dcbd3e5b7403567e96e4ac52d6941438b7fbef773f3f32db156106f5')
prepare() {
cd ${_gemname}-${pkgver}
sed 's|git ls-files|find|' -i ${_gemname}.gemspec
sed 's|~>|>=|g' -i ${_gemname}.gemspec # don't give a fuck about rubys bla bla
}
build() {
cd ${_gemname}-${pkgver}
gem build ${_gemname}.gemspec
}
package() {
cd ${_gemname}-${pkgver}
local _gemdir="$(gem env gemdir)"
gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" \
-n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 README.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
cd "${pkgdir}/${_gemdir}"
rm -rf cache gems/${_gemname}-${pkgver}/{ext,lib/*/*.so} \
extensions/*/*/${_gemname}-${pkgver}/{mkmf.log,gem_make.out}
}
# vim: ts=2 sw=2 et:
|