blob: d048985ae5f480f8fd5a79925a654b82c7c91734 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
_gemname=async-io
pkgname=ruby-${_gemname}
pkgver=1.12.2
pkgrel=1
pkgdesc='Provides support for asynchonous TCP, UDP, UNIX and SSL sockets'
url='https://github.com/socketry/async-io'
arch=('any')
license=('MIT')
depends=('ruby' 'ruby-async')
makedepends=('ruby-rdoc')
options=('!emptydirs')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/socketry/async-io/archive/v${pkgver}.tar.gz)
sha256sums=('65a5466957f7ad844a6e7f0d60adb1e06013beb1598eab783460b68c0998374c')
sha512sums=('aaecafbc7a4c4337b866929688b91a16d752ba74a7a3120f9a14ae308576fa71e7529790377d5767c2eda676f1223903edae9daa80892792704dc54a4502b16c')
prepare() {
cd ${_gemname}-${pkgver}
sed 's|git ls-files|find|' -i ${_gemname}.gemspec
sed 's|~>|>=|g' -i ${_gemname}.gemspec # don't give a fuck about rubys bla bla
}
build() {
cd ${_gemname}-${pkgver}
gem build ${_gemname}.gemspec
}
package() {
cd ${_gemname}-${pkgver}
local _gemdir="$(gem env gemdir)"
gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 README.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
rm "${pkgdir}"/${_gemdir}/cache/${_gemname}-${pkgver}.gem
}
# vim: ts=2 sw=2 et:
|