blob: 6be1d1a9a23c4e4a3e23d8f00c510ca10a5520ac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Maintainer: Mario Finelli <mario at finel dot li>
_gemname=flay
pkgname=ruby-$_gemname
pkgver=2.13.3
pkgrel=1
pkgdesc="Analyzes code for structural similarities"
arch=(any)
url=https://github.com/seattlerb/flay
license=(MIT)
options=(!emptydirs)
depends=(ruby ruby-erubi ruby-path_expander ruby-ruby2ruby ruby-ruby_parser
ruby-sexp_processor)
checkdepends=(ruby-minitest ruby-racc)
makedepends=(ruby-hoe ruby-rake ruby-rdoc rubygems)
source=(${url}/archive/v${pkgver}/$_gemname-$pkgver.tar.gz)
sha256sums=('c656e6fc71f1995123a81ac3c70c4137c4a3a5f73044ca718b80390f45c14e18')
prepare() {
cd $_gemname-$pkgver
# there is no license file in the repo, but we can extract one
sed '/== License:/,$!d' README.rdoc > LICENSE
}
build() {
cd $_gemname-$pkgver
local _gemdir="$(gem env gemdir)"
rake gem
gem install \
--local \
--verbose \
--ignore-dependencies \
--no-user-install \
--install-dir "tmp_install/${_gemdir}" \
--bindir "tmp_install/usr/bin" \
"pkg/${_gemname}-${pkgver}.gem"
# remove unrepreducible files
rm --force --recursive --verbose \
"tmp_install/${_gemdir}/cache/" \
"tmp_install/${_gemdir}/gems/${_gemname}-${pkgver}/vendor/" \
"tmp_install/${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"
find "tmp_install/${_gemdir}/gems/" \
-type f \
\( \
-iname "*.o" -o \
-iname "*.c" -o \
-iname "*.so" -o \
-iname "*.time" -o \
-iname "gem.build_complete" -o \
-iname "Makefile" \
\) \
-delete
find "tmp_install/${_gemdir}/extensions/" \
-type f \
\( \
-iname "mkmf.log" -o \
-iname "gem_make.out" \
\) \
-delete
}
check() {
cd $_gemname-$pkgver
local _gemdir="$(gem env gemdir)"
GEM_HOME="tmp_install/${_gemdir}" rake test
}
package() {
cd $_gemname-$pkgver
cp --archive --verbose tmp_install/* "${pkgdir}"
install -v -Dm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -v -Dm0644 *.rdoc -t "${pkgdir}/usr/share/doc/${pkgname}"
}
# vim: set ts=2 sw=2 et:
|