blob: d0aa22f81e05814d43cff0a924fb7615bbd52fcd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Mario Finelli <mario at finel dot li>
_gemname=git
pkgname=ruby-$_gemname
pkgver=1.9.1
pkgrel=1
pkgdesc="Ruby library to manipulate git repositories by wrapping system calls to the git binary"
arch=(any)
url=https://github.com/schacon/ruby-git
license=(MIT)
depends=(ruby git)
makedepends=(rubygems ruby-rdoc)
source=(git+https://github.com/ruby-git/ruby-git.git?tag=v$pkgver)
sha256sums=('SKIP')
prepare() {
cd ${pkgname}
sed -i 's|~>|>=|g' ${_gemname}.gemspec
}
build() {
cd ${pkgname}
gem build ${_gemname}.gemspec
}
package() {
cd ${pkgname}
local _gemdir="$(gem env gemdir)"
gem install \
--ignore-dependencies \
--no-user-install \
-i "$pkgdir/$_gemdir" \
-n "$pkgdir/usr/bin" \
$_gemname-$pkgver.gem
rm "$pkgdir/$_gemdir/cache/$_gemname-$pkgver.gem"
install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# vim: set ts=2 sw=2 et:
|