PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor: Andrea Scarpino <bash.lnx@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>
# Contributor: <stefanh-husmann@t-online.de>
# Contributor: Alexsandr Pavlov <kidoz at mail dot ru>

_gemname=hpricot
pkgname=ruby-$_gemname
pkgver=0.8.6
pkgrel=12
pkgdesc='A swift, liberal HTML parser with a fantastic library'
arch=(x86_64)
url='https://github.com/hpricot/hpricot'
license=(MIT)
depends=(ruby)
options=(!emptydirs)
source=(https://rubygems.org/downloads/$_gemname-$pkgver.gem)
noextract=($_gemname-$pkgver.gem)
sha1sums=('87ce2c17960a5e1d7ceaa16d0591ca6a28379ce0')

package() {
  local _gemdir="$(ruby -e'puts Gem.default_dir')"
  local _platform="$(gem env platform | cut -d':' -f2)"
  local _extension_api_version="$(ruby -e'puts Gem.extension_api_version')"
  gem install --ignore-dependencies --no-user-install --no-document -i "$pkgdir/$_gemdir" -n "$pkgdir/usr/bin" $_gemname-$pkgver.gem
  install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/COPYING" "$pkgdir/usr/share/licenses/$pkgname/COPYING"

  rm "$pkgdir/$_gemdir/cache/$_gemname-$pkgver.gem" \
      "${pkgdir}/${_gemdir}/extensions/${_platform}/${_extension_api_version}/${_gemname}-${pkgver}/gem_make.out"
  rm -r "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/test" \
      "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/ext"
}