blob: 1905ace4958c03e6c66dd8a3f1210cc023db6ece (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: Mario Finelli <mario at finel dot li>
_gemname=jaro_winkler
pkgname=ruby-${_gemname}
pkgver=1.5.6
pkgrel=1
pkgdesc="Ruby & C implementation of Jaro-Winkler distance algorithm"
arch=(i686 x86_64)
depends=(ruby)
makedepends=(rubygems ruby-rdoc)
checkdepends=(ruby-rake ruby-rake-compiler ruby-minitest)
url=https://github.com/tonytonyjan/jaro_winkler
license=(MIT)
options=(!emptydirs)
source=(https://github.com/tonytonyjan/jaro_winkler/archive/v$pkgver/$_gemname-$pkgver.tar.gz)
sha256sums=('b27eb01c660e965898239f069e13634b83793d88569b2ddc22d3dbe97a3277d3')
build() {
cd ${_gemname}-${pkgver}
local _gemdir="$(gem env gemdir)"
gem build "${_gemname}.gemspec"
gem install \
--local \
--verbose \
--ignore-dependencies \
--no-user-install \
--install-dir "tmp_install/${_gemdir}" \
--bindir "tmp_install/usr/bin" \
"${_gemname}-${pkgver}.gem"
# remove unrepreducible files
rm --force --recursive --verbose \
"tmp_install/${_gemdir}/cache/" \
"tmp_install/${_gemdir}/gems/${_gemname}-${pkgver}/vendor/" \
"tmp_install/${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"
find "tmp_install/${_gemdir}/gems/" \
-type f \
\( \
-iname "*.o" -o \
-iname "*.c" -o \
-iname "*.so" -o \
-iname "*.time" -o \
-iname "gem.build_complete" -o \
-iname "Makefile" \
\) \
-delete
find "tmp_install/${_gemdir}/extensions/" \
-type f \
\( \
-iname "mkmf.log" -o \
-iname "gem_make.out" \
\) \
-delete
}
check() {
cd ${_gemname}-${pkgver}
local _gemdir="$(gem env gemdir)"
GEM_HOME="tmp_install/${_gemdir}" rake
}
package() {
cd ${_gemname}-${pkgver}
cp --archive --verbose tmp_install/* "${pkgdir}"
install -v -Dm0644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -v -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -v -Dm0644 CHANGELOG.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG.md"
}
# vim: set ts=2 sw=2 et:
|