blob: fbee2ba1afbf9aff18922690f90d882f421d1629 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Mario Finelli <mario at finel dot li>
# Contributor: farwayer <farwayer at gmail dot com>
# Contributor: Andy Weidenbaum <archbaum at gmail dot com>
_gemname=parser
pkgname=ruby-${_gemname}
pkgver=3.1.2.1
pkgrel=1
pkgdesc="A Ruby parser written in pure Ruby"
arch=(any)
depends=(ruby ruby-ast)
checkdepends=(ruby-rake ruby-minitest)
makedepends=(rubygems ruby-rdoc ragel ruby-racc ruby-cliver ruby-rake ruby-bundler)
url=https://github.com/whitequark/parser
license=(MIT)
source=(https://github.com/whitequark/parser/archive/v$pkgver/$_gemname-$pkgver.tar.gz)
options=(!emptydirs)
sha256sums=('0b1ebcc4fe28a6b61a758e4a0129a0f770c52f4d5ef0d69fad70bc068410ec44')
prepare() {
cd $_gemname-$pkgver
sed -i 's|~>|>=|g' ${_gemname}.gemspec
sed -i '/simplecov/d' ${_gemname}.gemspec
sed -i '/kramdown/d' ${_gemname}.gemspec
sed -i '/gauntlet/d' ${_gemname}.gemspec
sed -i '/yard/d' ${_gemname}.gemspec
sed -i "s/require 'simplecov'//" test/helper.rb
}
build() {
cd $_gemname-$pkgver
# we need to use racc from ruby-racc not what's shipped with ruby
PATH="$(ruby -e 'puts Gem.dir')/bin:$PATH" rake generate
gem build ${_gemname}.gemspec
}
check() {
cd $_gemname-$pkgver
rake test
}
package() {
cd $_gemname-$pkgver
local _gemdir="$(gem env gemdir)"
gem install \
--ignore-dependencies \
--no-user-install \
-i "$pkgdir/$_gemdir" \
-n "$pkgdir/usr/bin" \
"$_gemname-$pkgver.gem"
rm -rf "$pkgdir/$_gemdir/cache"
install -Dm0644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm0644 CHANGELOG.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG.md"
}
# vim: set ts=2 sw=2 et:
|