blob: e98ac822ed09778bb30ba12b55a5638d7fcf51d2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Mario Finelli <mario at finel dot li>
# Contributor: farwayer <farwayer at gmail dot com>
# Contributor: Andy Weidenbaum <archbaum at gmail dot com>
_gemname=parser
pkgname=ruby-${_gemname}
pkgver=3.0.0.0
pkgrel=3
pkgdesc="A Ruby parser written in pure Ruby"
arch=(any)
depends=(ruby ruby-ast)
makedepends=(rubygems ruby-rdoc ragel ruby-racc ruby-cliver ruby-rake ruby-bundler)
url=https://github.com/whitequark/parser
license=(MIT)
source=(https://github.com/whitequark/parser/archive/v$pkgver/$_gemname-$pkgver.tar.gz)
options=(!emptydirs)
sha256sums=('1c471a145ab8694778409d9325da044dd7f719385d94986f38cae3d976dccbde')
prepare() {
cd $_gemname-$pkgver
sed -i 's|~>|>=|g' ${_gemname}.gemspec
}
build() {
cd $_gemname-$pkgver
rake generate
gem build ${_gemname}.gemspec
}
package() {
cd $_gemname-$pkgver
local _gemdir="$(gem env gemdir)"
gem install \
--ignore-dependencies \
--no-user-install \
-i "$pkgdir/$_gemdir" \
-n "$pkgdir/usr/bin" \
$_gemname-$pkgver.gem
rm "$pkgdir/$_gemdir/cache/$_gemname-$pkgver.gem"
install -Dm0644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# vim: set ts=2 sw=2 et:
|