blob: 23322cc96101641857c7de19e52e6d076882a33f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
# Contributor: Dmitry Kharitonov <arch[at]nano-model[dot]com>
# Contributor: kusakata <shohei atmark kusakata period com>
pkgname=ruby-pdf-reader
_name=${pkgname#ruby-}
pkgver=2.12.0
pkgrel=1
pkgdesc="Ruby library that implements a PDF parser conforming as much as possible to the PDF specification from Adobe"
arch=(any)
url="https://github.com/yob/pdf-reader"
license=(MIT)
depends=(
ruby
ruby-afm
ruby-ascii85
ruby-hashery
ruby-ruby-rc4
ruby-ttfunk
)
makedepends=(rubygems)
checkdepends=(ruby-rspec)
options=(!emptydirs)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('afb01b71579a0d36d8e0ddb6324251c4f7598dd2cee9c5909801cd953171b928')
_archive="$_name-$pkgver"
prepare() {
cd "$_archive"
# Update gemspec/Gemfile to allow newer version of the dependencies
sed -i -E 's|~>|>=|g' "$_name.gemspec"
sed -i -E 's|"< 13.0"|">= 13.0"|g' "$_name.gemspec"
# Remove bundler
sed -i '/require "bundler"/d' spec/spec_helper.rb
sed -i '/Bundler.setup/d' spec/spec_helper.rb
}
build() {
cd "$_archive"
local gemdir="$(gem env gemdir)"
gem build "$_name.gemspec"
gem install \
--local \
--verbose \
--ignore-dependencies \
--no-user-install \
--install-dir "tmp_install/$gemdir" \
--bindir "tmp_install/usr/bin" \
"$_name-$pkgver.gem"
# Remove unrepreducible files
rm --force --recursive --verbose \
"tmp_install/$gemdir/cache/" \
"tmp_install/$gemdir/gems/$_name-$pkgver/vendor/" \
"tmp_install/$gemdir/doc/$_name-$pkgver/ri/ext/"
find "tmp_install/$gemdir/gems/" \
-type f \
\( \
-iname "*.o" -o \
-iname "*.c" -o \
-iname "*.so" -o \
-iname "*.time" -o \
-iname "gem.build_complete" -o \
-iname "Makefile" \
\) \
-delete
find "tmp_install/$gemdir/extensions/" \
-type f \
\( \
-iname "mkmf.log" -o \
-iname "gem_make.out" \
\) \
-delete
}
check() {
cd "$_archive"
GEM_HOME="tmp_install/$(gem env gemdir)" rspec
}
package() {
cd "$_archive"
cp -a -t "$pkgdir" tmp_install/*
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" MIT-LICENSE
}
|