blob: f8c4bd91e2d877f5ace81184887dba559fb002d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
# Contributor: Anatoly Bashmakov <anatoly at posteo dot net>
pkgname=ruby-prawn-templates
_pkgname=${pkgname#ruby-}
pkgver=0.1.2
pkgrel=7
pkgdesc="Experimental extraction of template features from Prawn"
arch=(any)
url="https://github.com/prawnpdf/prawn-templates"
license=(
GPL-2.0-only
GPL-3.0-only
Ruby
)
depends=(
ruby
ruby-pdf-reader
ruby-prawn
)
makedepends=(ruby-rdoc)
checkdepends=(
ruby-pdf-inspector
ruby-rspec
)
options=(!emptydirs)
source=(
"$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz"
"remove-failing-tests.patch"
)
sha256sums=(
'116c18d2977db506cadc1e168cbb2ee7fb5d9f9abc9fd25d4a2265f9404c554a'
'9c095ca8b0aa4c033e1eda6a2c750386ee2d2b3ed018e97464d2994a003d6395'
)
_archive="$_pkgname-$pkgver"
prepare() {
cd "$_archive"
# Update gemspec/Gemfile to allow newer version of the dependencies
sed -i -E 's|~>|>=|g' "$_pkgname.gemspec"
patch --forward --strip=1 --input="$srcdir/remove-failing-tests.patch"
}
build() {
cd "$_archive"
local gemdir="$(gem env gemdir)"
gem build "$_pkgname.gemspec"
gem install \
--local \
--verbose \
--ignore-dependencies \
--no-user-install \
--install-dir "tmp_install/$gemdir" \
--bindir "tmp_install/usr/bin" \
"$_pkgname-$pkgver.gem"
# Remove unrepreducible files
rm --force --recursive --verbose \
"tmp_install/$gemdir/cache/" \
"tmp_install/$gemdir/gems/$_pkgname-$pkgver/vendor/" \
"tmp_install/$gemdir/doc/$_pkgname-$pkgver/ri/ext/"
find "tmp_install/$gemdir/gems/" \
-type f \
\( \
-iname "*.o" -o \
-iname "*.c" -o \
-iname "*.so" -o \
-iname "*.time" -o \
-iname "gem.build_complete" -o \
-iname "Makefile" \
\) \
-delete
find "tmp_install/$gemdir/extensions/" \
-type f \
\( \
-iname "mkmf.log" -o \
-iname "gem_make.out" \
\) \
-delete
}
check() {
cd "$_archive"
# Avoid depending on rubocop
sed -i '/rubocop/d' Rakefile "$_pkgname.gemspec"
GEM_HOME="tmp_install/$(gem env gemdir)" rspec
}
package() {
cd "$_archive"
cp -a -t "$pkgdir" tmp_install/*
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" \
COPYING LICENSE
}
|