PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78

# Maintainer: Komeil Parseh <ahmdparsh129@gmail.com>

pkgname=ruby-repofetch
_gitname=repofetch
pkgver=v0.4.3.r2.gf5d5be4
pkgrel=1
pkgdesc="A remote repository stat fetcher with support for 3rd-party plugins devel version."
arch=('any')
url="https://spenserblack.github.io/repofetch/"
gh_url="https://github.com/spenserblack/repofetch"
license=('MIT')
makedepends=('git')
optdepends=('github-cli: Receive auth token from GitHub')
depends=('ruby')
provides=('ruby-repofetch')
conflicts=('ruby-repofetch' 'ruby-repofetch-bin')
source=("${pkgname}::git+${gh_url}")
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}/${pkgname}"
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  cd "${srcdir}/${pkgname}"

  local _gemdir="$(gem env gemdir)"

  gem build -o "${_gitname}.gem" "${_gitname}.gemspec"

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "tmp_install/${_gemdir}" \
    --bindir "tmp_install/usr/bin" \
    "${_gitname}.gem"

  # remove unrepreducible files
  rm --force --recursive --verbose \
    "tmp_install/${_gemdir}/cache/" \
    "tmp_install/${_gemdir}/gems/${srcdir}/${pkgname}/vendor/" \
    "tmp_install/${_gemdir}/doc/${srcdir}/${pkgname}/ri/ext/"

  find "tmp_install/${_gemdir}/gems/" \
    -type f \
    \( \
      -iname "*.o" -o \
      -iname "*.c" -o \
      -iname "*.so" -o \
      -iname "*.time" -o \
      -iname "gem.build_complete" -o \
      -iname "Makefile" \
    \) \
    -delete

  find "tmp_install/${_gemdir}/extensions/" \
    -type f \
    \( \
      -iname "mkmf.log" -o \
      -iname "gem_make.out" \
    \) \
    -delete
}

package() {
  cd "${srcdir}/${pkgname}"

  cp --archive --verbose tmp_install/* "${pkgdir}"

  install --verbose -D --mode=0644 LICENSE --target-directory "${pkgdir}/usr/share/licenses/${pkgname}"
  install --verbose -D --mode=0644 *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}