blob: 12fdb0e18b3d3c1c5498f288b9d6d4303bf58fc4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Mario Finelli <mario at finel dot li>
# Contributor: farwayer <farwayer at gmail dot com>
_gemname=rubocop
pkgname=ruby-${_gemname}
pkgver=1.8.1
pkgrel=1
pkgdesc="A Ruby static code analyzer and formatter"
arch=(any)
depends=(
ruby
ruby-parallel
ruby-parser
ruby-rainbow
ruby-regexp_parser
ruby-rexml
ruby-rubocop-ast
ruby-ruby-progressbar
ruby-unicode-display_width
)
makedepends=(rubygems ruby-rdoc)
url=https://rubocop.org
license=(MIT)
options=(!emptydirs)
source=(https://github.com/rubocop-hq/rubocop/archive/v$pkgver/$_gemname-$pkgver.tar.gz)
sha256sums=('62e9da709f4650acccc640d57dfd091edaf9c887d09c52ea52b369eb006219c1')
prepare() {
cd $_gemname-$pkgver
sed -i 's|~>|>=|g' ${_gemname}.gemspec
}
build() {
cd $_gemname-$pkgver
gem build ${_gemname}.gemspec
}
package() {
cd $_gemname-$pkgver
local _gemdir="$(gem env gemdir)"
gem install \
--ignore-dependencies \
--no-user-install \
-i "$pkgdir/$_gemdir" \
-n "$pkgdir/usr/bin" \
$_gemname-$pkgver.gem
rm "$pkgdir/$_gemdir/cache/$_gemname-$pkgver.gem"
install -Dm0644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim: set ts=2 sw=2 et:
|