blob: 9671b20a716e4a4df9e883456ee57ced35a94de2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Maintainer: Mario Finelli <mario at finel dot li>
# Contributor: farwayer <farwayer at gmail dot com>
_gemname=rubocop
pkgname=ruby-${_gemname}
pkgver=1.37.1
pkgrel=1
pkgdesc="A Ruby static code analyzer and formatter"
arch=(any)
depends=(
ruby
ruby-parallel
ruby-parser
ruby-rainbow
ruby-regexp_parser
ruby-rexml
ruby-rubocop-ast
ruby-ruby-progressbar
ruby-unicode-display_width
)
checkdepends=(
ruby-bundler
ruby-rake
ruby-rspec
ruby-webmock
ruby-rubocop-rspec
ruby-rubocop-performance
ruby-rubocop-rake
ruby-test-queue
ruby-yard
ruby-bump
ruby-rubocop-rails
)
makedepends=(rubygems ruby-rdoc)
url=https://rubocop.org
license=(MIT)
options=(!emptydirs)
source=(https://github.com/rubocop/rubocop/archive/v$pkgver/$_gemname-$pkgver.tar.gz)
sha256sums=('e1fdf44fb255767c6c3b0232a06751854a75a9713f5719ef19bb88855d3d90b8')
prepare() {
cd $_gemname-$pkgver
sed -i 's|~>|>=|g' ${_gemname}.gemspec
sed -i '/asciidoctor/d' Gemfile
sed -i '/memory_profiler/d' Gemfile
sed -i '/simplecov/d' Gemfile
sed -i '/stackprof/d' Gemfile
sed -i 's|~>|>=|g' Gemfile
sed -i '/group/d' Gemfile
sed -i '/end/d' Gemfile
}
build() {
cd $_gemname-$pkgver
gem build ${_gemname}.gemspec
}
check() {
cd $_gemname-$pkgver
rake spec
rake ascii_spec
}
package() {
cd $_gemname-$pkgver
local _gemdir="$(gem env gemdir)"
gem install \
--ignore-dependencies \
--no-user-install \
-i "$pkgdir/$_gemdir" \
-n "$pkgdir/usr/bin" \
$_gemname-$pkgver.gem
rm -rf "$pkgdir/$_gemdir/cache"
install -Dm0644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm0644 CHANGELOG.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG.md"
}
# vim: set ts=2 sw=2 et:
|