blob: c408254be4092915112caace6165ecb3741d2457 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Mario Finelli <mario at finel dot li>
_gemname=rubocop-rails
pkgname=ruby-${_gemname}
pkgver=2.17.2
pkgrel=1
pkgdesc="Automatic Rails code style checking tool"
arch=(any)
depends=(ruby ruby-rubocop ruby-activesupport ruby-rack)
checkdepends=(ruby-bundler ruby-rake ruby-rspec ruby-yard ruby-bump
ruby-rubocop-performance ruby-rubocop-rspec ruby-test-queue)
makedepends=(rubygems ruby-rdoc)
url=https://docs.rubocop.org/rubocop-rails/
license=(MIT)
options=(!emptydirs)
source=(https://github.com/rubocop/rubocop-rails/archive/v$pkgver/$_gemname-$pkgver.tar.gz)
sha256sums=('d7758329119eaa7b39abd84c5eea49fcc55cdb7bafadbe43eca4ffc3172a302b')
prepare() {
cd $_gemname-$pkgver
sed -i '/yard/d' Gemfile
sed -i '/simplecov/d' Gemfile
sed -i "s/, github: 'rubocop\/rubocop'//" Gemfile
sed -i 's|git ls-files|find|' ${_gemname}.gemspec
sed -i 's|~>|>=|g' Gemfile
}
build() {
cd $_gemname-$pkgver
gem build ${_gemname}.gemspec
}
check() {
cd $_gemname-$pkgver
rake spec
}
package() {
cd $_gemname-$pkgver
local _gemdir="$(ruby -e'puts Gem.default_dir')"
gem install \
--ignore-dependencies \
--no-user-install \
-i "$pkgdir/$_gemdir" \
-n "$pkgdir/usr/bin" \
$_gemname-$pkgver.gem
rm -rf "$pkgdir/$_gemdir/cache"
install -Dm0644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm0644 CHANGELOG.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG.md"
}
# vim: set ts=2 sw=2 et:
|