blob: 8b6bed1d3fd8ca9b581ef80d3dbe99df8f0fc0b1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Andrea Richiardi <a.richiardi.work@gmail.com>
# Contributor: Jeremy Audet <jerebear@protonmail.com>
# Contributor: Julien Nicoulaud <julien.nicoulaud@gmail.com>
_gemname=sexp_processor
pkgname="ruby-${_gemname}"
pkgver=4.17.0
pkgrel=1
pkgdesc="A branch of ParseTree that brings several sexp processing tools."
arch=(any)
url="https://github.com/seattlerb/sexp_processor"
license=(MIT)
depends=(ruby)
makedepends=(ruby-rdoc)
options=(!emptydirs)
source=("https://rubygems.org/downloads/${_gemname}-${pkgver}.gem")
noextract=("${_gemname}-${pkgver}.gem")
sha256sums=('4daa4874ce1838cd801c65e66ed5d4f140024404a3de7482c36d4ef2604dff6f')
package() {
local _gemdir="$(ruby -e 'puts Gem.default_dir')"
# install gem
HOME=/tmp gem install \
--no-user-install \
--ignore-dependencies \
--install-dir "${pkgdir}${_gemdir}" \
--bindir "${pkgdir}/usr/bin" \
"${srcdir}/${_gemname}-${pkgver}.gem"
# install license. Using `install` lets us ensure dest directory exists and
# permissions are OK. Unfortunately, it only works with files, not stdin.
local _license="$(mktemp)"
sed -n '/LICENSE:/,$ p' \
"${pkgdir}${_gemdir}/gems/${_gemname}-${pkgver}/README.rdoc" > "${_license}"
install -Dm 644 "${_license}" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
rm "${_license}"
}
# vim:set ts=2 sw=2 et:
|