blob: f7765bea3b3a79b0dc74a5df010e426de21b767f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Jeremy "Ichimonji10" Audet <ichimonji10 at gmail dot com>
# Contributor: Julien Nicoulaud <julien.nicoulaud@gmail.com>
_gemname=sexp_processor
pkgname="ruby-${_gemname}"
pkgver=4.7.0
pkgrel=1
pkgdesc="A branch of ParseTree that brings several sexp processing tools."
arch=(any)
url="https://github.com/seattlerb/sexp_processor"
license=(MIT)
depends=(ruby)
makedepends=(rubygems)
options=(!emptydirs)
source=("http://gems.rubyforge.org/gems/${_gemname}-${pkgver}.gem")
noextract=("${_gemname}-${pkgver}.gem")
sha256sums=('963a1f5b21c95595fb3cf1e8531784bf3d8fe30302cf6f271b08aefdc63e453f')
package() {
local _gemdir="$(ruby -rubygems -e 'puts Gem.default_dir')"
# install gem
HOME=/tmp gem install \
--no-user-install \
--ignore-dependencies \
--install-dir "${pkgdir}${_gemdir}" \
--bindir "${pkgdir}/usr/bin" \
"${srcdir}/${_gemname}-${pkgver}.gem"
# install license. Using `install` lets us ensure dest directory exists and
# permissions are OK. Unfortunately, it only works with files, not stdin.
local _license="$(mktemp)"
sed -n '/LICENSE:/,$ p' \
"${pkgdir}${_gemdir}/gems/${_gemname}-${pkgver}/README.txt" > "${_license}"
install -Dm 644 "$_license" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
rm "${_license}"
}
# vim:set ts=2 sw=2 et:
|