blob: 5049854a3dceb54bd709be32a2053a9515b462f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Mario Finelli <mario at finel dot li>
# Contributor: Artem Vorotnikov <artem@vorotnikov.me>
_gemname=slim
pkgname=ruby-$_gemname
pkgver=4.1.0
pkgrel=1
pkgdesc="a template language whose goal is reduce the syntax to the essential parts"
arch=(any)
url=http://slim-lang.com
license=(MIT)
depends=(ruby ruby-temple ruby-tilt)
checkdepends=(ruby-rake ruby-rack-test ruby-benchmark-ips ruby-erubis ruby-haml ruby-sassc ruby-kramdown ruby-minitest)
makedepends=(git rubygems ruby-rdoc)
options=(!emptydirs)
source=(git+https://github.com/slim-template/slim.git?tag=v$pkgver)
sha256sums=('SKIP')
prepare() {
cd ${_gemname}
# TODO: open PR upstream
sed -i "/require 'helper'/a require 'ostruct'" test/core/test_code_evaluation.rb
sed -i 's/OpenStruct/::OpenStruct/' test/core/test_code_evaluation.rb
}
build() {
cd ${_gemname}
gem build ${_gemname}.gemspec
}
check() {
cd ${_gemname}
rake test
}
package() {
cd ${_gemname}
local _gemdir="$(gem env gemdir)"
gem install \
--ignore-dependencies \
--no-user-install \
-i "$pkgdir/$_gemdir" \
-n "$pkgdir/usr/bin" \
$_gemname-$pkgver.gem
rm -rf "$pkgdir/$_gemdir/cache"
install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm0644 CHANGES "$pkgdir/usr/share/doc/$pkgname/CHANGELOG"
}
# vim: set ts=2 sw=2 et:
|