blob: 67c5502d4cf01120d88b116ce72a4a672dbed3b3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Eivind Eide <xenofil AT gmail DOT com>
# Contributor: Alexander F Rødseth <xyproto AT archlinux DOT org>
# Contributor: Maxime Gauduin <alucryd AT gmail DOT com>
# Contributor: Dave Reisner <dreisner AT archlinux DOT org>
# Contributor: Alexander Fehr <pizzapunk AT gmail DOT com>
pkgname=rubyripper
pkgver=0.7.0rc2
pkgrel=1
pkgdesc='Secure audiodisc ripper'
arch=('any')
url='http://code.google.com/p/rubyripper/'
license=('GPL3')
depends=('cdparanoia' 'gtk2' 'ruby-iconv')
optdepends=('ruby-gtk2: GTK+ GUI'
'cd-discid: Freedb support'
'lame: MP3 encoding support'
'vorbis-tools: Ogg Vorbis encoding support'
'flac: FLAC encoding support'
'wavegain: WAV ReplayGain support'
'mp3gain: MP3 ReplayGain support'
'vorbisgain: Ogg Vorbis ReplayGain support'
'normalize: Normalization support'
'cdrdao: Advanced TOC analysis'
'sox: Correct pre-emphasis with sox'
'wavpack: WavPack encoding support'
'opus-tools: Opus encoding support'
'neroaacenc-bin: Nero AAC encoding support')
source=("https://github.com/bleskodev/rubyripper/archive/v$pkgver.tar.gz")
sha256sums=('977089c4a262936f9acf82ad1ab5932de97523ba31b61b5ccc1279a94eaea6ae')
build() {
cd "${pkgname}-${pkgver}"
./configure --prefix='/usr' --enable-{cli,gtk2} \
--ruby="$(ruby -e 'v = RbConfig::CONFIG["vendorlibdir"] ; v["/usr"] = ""; puts v')"
}
package() {
make DESTDIR="$pkgdir" -C "$pkgname-$pkgver" install
}
# vim: ts=2 sw=2 et:
|